Mojo::Pg(3) Mojolicious ♥ PostgreSQL

SYNOPSIS


use Mojo::Pg;
# Select the server version
my $pg = Mojo::Pg->new('postgresql://[email protected]/test');
say $pg->db->query('select version() as version')->hash->{version};
# Use migrations to create a table
$pg->migrations->name('my_names_app')->from_string(<<EOF)->migrate;
-- 1 up
create table names (id serial primary key, name text);
-- 1 down
drop table names;
EOF
# Use migrations to drop and recreate the table
$pg->migrations->migrate(0)->migrate;
# Insert a few rows
my $db = $pg->db;
$db->query('insert into names (name) values (?)', 'Sara');
$db->query('insert into names (name) values (?)', 'Stefan');
# Insert more rows in a transaction
eval {
my $tx = $db->begin;
$db->query('insert into names (name) values (?)', 'Baerbel');
$db->query('insert into names (name) values (?)', 'Wolfgang');
$tx->commit;
};
say [email protected] if [email protected];
# Insert another row and return the generated id
say $db->query('insert into names (name) values (?) returning id', 'Daniel')
->hash->{id};
# JSON roundtrip
say $db->query('select ?::json as foo', {json => {bar => 'baz'}})
->expand->hash->{foo}{bar};
# Select one row at a time
my $results = $db->query('select * from names');
while (my $next = $results->hash) {
say $next->{name};
}
# Select all rows blocking
say $_->{name} for $db->query('select * from names')->hashes->each;
# Select all rows non-blocking
$db->query('select * from names' => sub {
my ($db, $err, $results) = @_;
die $err if $err;
say $_->{name} for $results->hashes->each;
});
Mojo::IOLoop->start unless Mojo::IOLoop->is_running;
# Concurrent non-blocking queries (synchronized with a delay)
Mojo::IOLoop->delay(
sub {
my $delay = shift;
$pg->db->query('select now() as now' => $delay->begin);
$pg->db->query('select * from names' => $delay->begin);
},
sub {
my ($delay, $time_err, $time, $names_err, $names) = @_;
if (my $err = $time_err || $names_err) { die $err }
say $time->hash->{now};
say $_->{name} for $names->hashes->each;
}
)->wait;
# Send and receive notifications non-blocking
$pg->pubsub->listen(foo => sub {
my ($pubsub, $payload) = @_;
say "foo: $payload";
$pubsub->notify(bar => $payload);
});
$pg->pubsub->listen(bar => sub {
my ($pubsub, $payload) = @_;
say "bar: $payload";
});
$pg->pubsub->notify(foo => 'PostgreSQL rocks!');
Mojo::IOLoop->start unless Mojo::IOLoop->is_running;

DESCRIPTION

Mojo::Pg is a tiny wrapper around DBD::Pg that makes PostgreSQL <http://www.postgresql.org> a lot of fun to use with the Mojolicious <http://mojolicious.org> real-time web framework.

Database and statement handles are cached automatically, and will be reused transparently to increase performance. You can handle connection timeouts gracefully by holding on to them only for short amounts of time.

  use Mojolicious::Lite;
  use Mojo::Pg;
  helper pg => sub { state $pg = Mojo::Pg->new('postgresql://[email protected]/test') };
  get '/' => sub {
    my $c  = shift;
    my $db = $c->pg->db;
    $c->render(json => $db->query('select now() as now')->hash);
  };
  app->start;

In this example application, we create a "pg" helper to store a Mojo::Pg object. Our action calls that helper and uses the method ``db'' in Mojo::Pg to dequeue a Mojo::Pg::Database object from the connection pool. Then we use the method ``query'' in Mojo::Pg::Database to execute an SQL <http://www.postgresql.org/docs/current/static/sql.html> statement, which returns a Mojo::Pg::Results object. And finally we call the method ``hash'' in Mojo::Pg::Results to retrieve the first row as a hash reference.

While all I/O operations are performed blocking, you can wait for long running queries asynchronously, allowing the Mojo::IOLoop event loop to perform other tasks in the meantime. Since database connections usually have a very low latency, this often results in very good performance.

Every database connection can only handle one active query at a time, this includes asynchronous ones. To perform multiple queries concurrently, you have to use multiple connections.

  # Performed concurrently (5 seconds)
  $pg->db->query('select pg_sleep(5)' => sub {...});
  $pg->db->query('select pg_sleep(5)' => sub {...});

All cached database handles will be reset automatically if a new process has been forked, this allows multiple processes to share the same Mojo::Pg object safely.

GROWING

And as your application grows, you can move queries into model classes.

  package MyApp::Model::Time;
  use Mojo::Base -base;
  has 'pg';
  sub now { shift->pg->db->query('select now() as now')->hash }
  1;

Which get integrated into your application with helpers.

  use Mojolicious::Lite;
  use Mojo::Pg;
  use MyApp::Model::Time;
  helper pg => sub { state $pg = Mojo::Pg->new('postgresql://[email protected]/test') };
  helper time => sub { state $time = MyApp::Model::Time->new(pg => shift->pg) };
  get '/' => sub {
    my $c = shift;
    $c->render(json => $c->time->now);
  };
  app->start;

EVENTS

Mojo::Pg inherits all events from Mojo::EventEmitter and can emit the following new ones.

connection

  $pg->on(connection => sub {
    my ($pg, $dbh) = @_;
    ...
  });

Emitted when a new database connection has been established.

  $pg->on(connection => sub {
    my ($pg, $dbh) = @_;
    $dbh->do('set search_path to my_schema');
  });

ATTRIBUTES

Mojo::Pg implements the following attributes.

auto_migrate

  my $bool = $pg->auto_migrate;
  $pg      = $pg->auto_migrate($bool);

Automatically migrate to the latest database schema with ``migrations'', as soon as the first database connection has been established.

dsn

  my $dsn = $pg->dsn;
  $pg     = $pg->dsn('dbi:Pg:dbname=foo');

Data source name, defaults to "dbi:Pg:".

max_connections

  my $max = $pg->max_connections;
  $pg     = $pg->max_connections(3);

Maximum number of idle database handles to cache for future use, defaults to 5.

migrations

  my $migrations = $pg->migrations;
  $pg            = $pg->migrations(Mojo::Pg::Migrations->new);

Mojo::Pg::Migrations object you can use to change your database schema more easily.

  # Load migrations from file and migrate to latest version
  $pg->migrations->from_file('/home/sri/migrations.sql')->migrate;

options

  my $options = $pg->options;
  $pg         = $pg->options({AutoCommit => 1, RaiseError => 1});

Options for database handles, defaults to activating "AutoCommit", "AutoInactiveDestroy" as well as "RaiseError" and deactivating "PrintError". Note that "AutoCommit" and "RaiseError" are considered mandatory, so deactivating them would be very dangerous.

password

  my $password = $pg->password;
  $pg          = $pg->password('s3cret');

Database password, defaults to an empty string.

pubsub

  my $pubsub = $pg->pubsub;
  $pg        = $pg->pubsub(Mojo::Pg::PubSub->new);

Mojo::Pg::PubSub object you can use to send and receive notifications very efficiently, by sharing a single database connection with many consumers.

  # Subscribe to a channel
  $pg->pubsub->listen(news => sub {
    my ($pubsub, $payload) = @_;
    say "Received: $payload";
  });
  # Notify a channel
  $pg->pubsub->notify(news => 'PostgreSQL rocks!');

search_path

  my $path = $pg->search_path;
  $pg      = $pg->search_path(['$user', 'foo', 'public']);

Schema search path assigned to all new connections.

  # Isolate tests and avoid race conditions when running them in parallel
  $pg->db->query('drop schema if exists test_one cascade');
  $pg->db->query('create schema test_one');
  $pg->search_path(['test_one']);
  ...
  $pg->db->query('drop schema test_one cascade');

username

  my $username = $pg->username;
  $pg          = $pg->username('sri');

Database username, defaults to an empty string.

METHODS

Mojo::Pg inherits all methods from Mojo::EventEmitter and implements the following new ones.

db

  my $db = $pg->db;

Get Mojo::Pg::Database object for a cached or newly established database connection. The DBD::Pg database handle will be automatically cached again when that object is destroyed, so you can handle problems like connection timeouts gracefully by holding on to it only for short amounts of time.

  # Add up all the money
  say $pg->db->query('select * from accounts')
    ->hashes->reduce(sub { $a->{money} + $b->{money} });

from_string

  $pg = $pg->from_string('postgresql://[email protected]/test');

Parse configuration from connection string.

  # Just a database
  $pg->from_string('postgresql:///db1');
  # Just a service
  $pg->from_string('postgresql://?service=foo');
  # Username and database
  $pg->from_string('postgresql://[email protected]/db2');
  # Username, password, host and database
  $pg->from_string('postgresql://sri:[email protected]/db3');
  # Username, domain socket and database
  $pg->from_string('postgresql://[email protected]%2ftmp%2fpg.sock/db4');
  # Username, database and additional options
  $pg->from_string('postgresql://[email protected]/db5?PrintError=1&pg_server_prepare=0');
  # Service and additional options
  $pg->from_string('postgresql://?service=foo&PrintError=1&RaiseError=0');

new

  my $pg = Mojo::Pg->new;
  my $pg = Mojo::Pg->new('postgresql://[email protected]/test');

Construct a new Mojo::Pg object and parse connection string with ``from_string'' if necessary.

  # Customize configuration further
  my $pg = Mojo::Pg->new->dsn('dbi:Pg:service=foo');

REFERENCE

This is the class hierarchy of the Mojo::Pg distribution.
  • Mojo::Pg
  • Mojo::Pg::Database
  • Mojo::Pg::Migrations
  • Mojo::Pg::PubSub
  • Mojo::Pg::Results
  • Mojo::Pg::Transaction

AUTHOR

Sebastian Riedel, "[email protected]".

CREDITS

In alphabetical order:

Dan Book

Hernan Lopes

William Lindley

COPYRIGHT AND LICENSE

Copyright (C) 2014-2016, Sebastian Riedel and others.

This program is free software, you can redistribute it and/or modify it under the terms of the Artistic License version 2.0.