SYNOPSIS

# This fails because the "post" method doesn't return
# $self; it returns an HTTP::Request object.
#
LWP::UserAgent
-> new
-> post('http://www.example.com/submit', \%data)
-> get('http://www.example.com/status');

# The 'tap' method runs some code and always returns $self.
#
LWP::UserAgent
-> new
-> tap(post => [ 'http://www.example.com/submit', \%data ])
-> get('http://www.example.com/status');

# Or use a coderef...
#
LWP::UserAgent
-> new
-> tap(sub { $_->post('http://www.example.com/submit', \%data) })
-> get('http://www.example.com/status');

DESCRIPTION

DO NOT USE THIS MODULE! Use Object::Tap or Object::Util instead. They are not drop-in replacements, but a far more sensible way to have a "tap" method.

This module has nothing to do with the Test Anything Protocol (TAP, see Test::Harness).

This module is a role for your class, providing it with a "tap" method. The "tap" method is an aid to chaining. You can do for example:

   $object
      ->tap( sub{ $_->foo(1) } )
      ->tap( sub{ $_->bar(2) } )
      ->tap( sub{ $_->baz(3) } );

... without worrying about what the "foo", "bar" and "baz" methods return, because "tap" always returns its invocant.

The "tap" method also provides a few shortcuts, so that the above can actually be written:

   $object->tap(foo => [1], bar => [2], baz => [3]);

... but more about that later. Anyway, this module provides one method for your class - "tap" - which is described below.

tap(@arguments)

This can be called as an object or class method, but is usually used as an object method.

Each argument is processed in the order given. It is processed differently, depending on the kind of argument it is.

Coderef arguments

An argument that is a coderef (or a blessed argument that overloads "&{}" - see overload) will be executed in a context where $_ has been set to the invocant of the tap method "tap". The return value of the coderef is ignored. For example:

   {
      package My::Class;
      use Role::Commons qw(Tap);
   }
   print My::Class->tap(
      sub { warn uc $_; return 'X' },
   );

... will warn ``MY::CLASS'' and then print ``My::Class''.

Because each argument to "tap" is processed in order, you can provide multiple coderefs:

   print My::Class->tap(
      sub { warn uc $_; return 'X' },
      sub { warn lc $_; return 'Y' },
   );

String arguments

A non-reference argument (i.e. a string) is treated as a shortcut for a method call on the invocant. That is, the following two taps are equivalent:

   $object->tap( sub{$_->foo(@_)} );
   $object->tap( 'foo' );

Arrayref arguments

An arrayref is dereferenced yielding a list. This list is passed as an argument list when executing the previous coderef argument (or string argument). The following three taps are equivalent:

   $object->tap(
      sub { $_->foo('bar', 'baz') },
   );
   $object->tap(
      sub { $_->foo(@_) },
      ['bar', 'baz'],
   );
   $object->tap(
      foo => ['bar', 'baz'],
   );

Scalar ref arguments

There are a handful of special scalar ref arguments that are supported:

"\"EVAL""

This indicates that you wish for all subsequent coderefs to be wrapped in an "eval", making any errors that occur within it non-fatal.

   $object->tap(\"EVAL", sub {...});

"\"NO_EVAL""

Switches back to the default behaviour of not wrapping coderefs in "eval".

   $object->tap(
      \"EVAL",
      sub {...},   # any fatal errors will be caught and ignored
      \"NO_EVAL",
      sub {...},   # fatal errors are properly fatal again.
   );

AUTHOR

Toby Inkster <[email protected]>.

COPYRIGHT AND LICENCE

This software is copyright (c) 2012, 2014 by Toby Inkster.

This is free software; you can redistribute it and/or modify it under the same terms as the Perl 5 programming language system itself.

DISCLAIMER OF WARRANTIES

THIS PACKAGE IS PROVIDED ``AS IS'' AND WITHOUT ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, WITHOUT LIMITATION, THE IMPLIED WARRANTIES OF MERCHANTIBILITY AND FITNESS FOR A PARTICULAR PURPOSE.