man WWW::Mechanize (3): Handy web browsing in a Perl object

VERSION

Version 1.75

SYNOPSIS

"WWW::Mechanize", or Mech for short, is a Perl module for stateful programmatic web browsing, used for automating interaction with websites.

Features include:

All HTTP methods
High-level hyperlink and HTML form support, without having to parse HTML yourself
SSL support
Automatic cookies
Custom HTTP headers
Automatic handling of redirections
Proxies
HTTP authentication

Mech supports performing a sequence of page fetches including following links and submitting forms. Each fetched page is parsed and its links and forms are extracted. A link or a form can be selected, form fields can be filled and the next page can be fetched. Mech also stores a history of the URLs you've visited, which can be queried and revisited.

use WWW::Mechanize;
my $mech = WWW::Mechanize->new();
$mech->get( $url );
$mech->follow_link( n => 3 );
$mech->follow_link( text_regex => qr/download this/i );
$mech->follow_link( url => 'http://host.com/index.html' );
$mech->submit_form(
form_number => 3,
fields => {
username => 'mungo',
password => 'lost-and-alone',
}
);
$mech->submit_form(
form_name => 'search',
fields => { query => 'pot of gold', },
button => 'Search Now'
);

Mech is well suited for use in testing web applications. If you use one of the Test::*, like Test::HTML::Lint modules, you can check the fetched content and use that as input to a test call.

    use Test::More;
    like( $mech->content(), qr/$expected/, "Got expected content" );

Each page fetch stores its URL in a history stack which you can traverse.

    $mech->back();

If you want finer control over your page fetching, you can use these methods. "follow_link" and "submit_form" are just high level wrappers around them.

    $mech->find_link( n => $number );
    $mech->form_number( $number );
    $mech->form_name( $name );
    $mech->field( $name, $value );
    $mech->set_fields( %field_values );
    $mech->set_visible( @criteria );
    $mech->click( $button );

WWW::Mechanize is a proper subclass of LWP::UserAgent and you can also use any of LWP::UserAgent's methods.

    $mech->add_header($name => $value);

Please note that Mech does NOT support JavaScript, you need additional software for that. Please check ``JavaScript'' in WWW::Mechanize::FAQ for more.

IMPORTANT LINKS

<http://code.google.com/p/www-mechanize/issues/list>
The queue for bugs & enhancements in WWW::Mechanize and Test::WWW::Mechanize. Please note that the queue at <http://rt.cpan.org> is no longer maintained.
<http://search.cpan.org/dist/WWW-Mechanize/>
The CPAN documentation page for Mechanize.
<http://search.cpan.org/dist/WWW-Mechanize/lib/WWW/Mechanize/FAQ.pod>
Frequently asked questions. Make sure you read here FIRST.

CONSTRUCTOR AND STARTUP

new()

Creates and returns a new WWW::Mechanize object, hereafter referred to as the ``agent''.

    my $mech = WWW::Mechanize->new()

The constructor for WWW::Mechanize overrides two of the parms to the LWP::UserAgent constructor:

    agent => 'WWW-Mechanize/#.##'
    cookie_jar => {}    # an empty, memory-only HTTP::Cookies object

You can override these overrides by passing parms to the constructor, as in:

    my $mech = WWW::Mechanize->new( agent => 'wonderbot 1.01' );

If you want none of the overhead of a cookie jar, or don't want your bot accepting cookies, you have to explicitly disallow it, like so:

    my $mech = WWW::Mechanize->new( cookie_jar => undef );

Here are the parms that WWW::Mechanize recognizes. These do not include parms that LWP::UserAgent recognizes.

"autocheck => [0|1]"
Checks each request made to see if it was successful. This saves you the trouble of manually checking yourself. Any errors found are errors, not warnings.
The default value is ON, unless it's being subclassed, in which case it is OFF. This means that standalone WWW::Mechanizeinstances have autocheck turned on, which is protective for the vast majority of Mech users who don't bother checking the return value of get() and post() and can't figure why their code fails. However, if WWW::Mechanize is subclassed, such as for Test::WWW::Mechanize or Test::WWW::Mechanize::Catalyst, this may not be an appropriate default, so it's off.
"noproxy => [0|1]"
Turn off the automatic call to the LWP::UserAgent "env_proxy" function.
This needs to be explicitly turned off if you're using Crypt::SSLeay to access a https site via a proxy server. Note: you still need to set your HTTPS_PROXY environment variable as appropriate.
"onwarn => \&func"
Reference to a "warn"-compatible function, such as "Carp::carp", that is called when a warning needs to be shown.
If this is set to "undef", no warnings will ever be shown. However, it's probably better to use the "quiet" method to control that behavior.
If this value is not passed, Mech uses "Carp::carp" if Carp is installed, or "CORE::warn" if not.
"onerror => \&func"
Reference to a "die"-compatible function, such as "Carp::croak", that is called when there's a fatal error.
If this is set to "undef", no errors will ever be shown.
If this value is not passed, Mech uses "Carp::croak" if Carp is installed, or "CORE::die" if not.
"quiet => [0|1]"
Don't complain on warnings. Setting "quiet => 1" is the same as calling "$mech->quiet(1)". Default is off.
"stack_depth => $value"
Sets the depth of the page stack that keeps track of all the downloaded pages. Default is effectively infinite stack size. If the stack is eating up your memory, then set this to a smaller number, say 5 or 10. Setting this to zero means Mech will keep no history.

To support forms, WWW::Mechanize's constructor pushes POST on to the agent's "requests_redirectable" list (see also LWP::UserAgent.)

$mech->agent_alias( $alias )

Sets the user agent string to the expanded version from a table of actual user strings. $alias can be one of the following:

Windows IE 6
Windows Mozilla
Mac Safari
Mac Mozilla
Linux Mozilla
Linux Konqueror

then it will be replaced with a more interesting one. For instance,

    $mech->agent_alias( 'Windows IE 6' );

sets your User-Agent to

    Mozilla/4.0 (compatible; MSIE 6.0; Windows NT 5.1)

The list of valid aliases can be returned from "known_agent_aliases()". The current list is:

Windows IE 6
Windows Mozilla
Mac Safari
Mac Mozilla
Linux Mozilla
Linux Konqueror

known_agent_aliases()

Returns a list of all the agent aliases that Mech knows about.

PAGE-FETCHING METHODS

$mech->get( $uri )

Given a URL/URI, fetches it. Returns an HTTP::Response object. $uri can be a well-formed URL string, a URI object, or a WWW::Mechanize::Link object.

The results are stored internally in the agent object, but you don't know that. Just use the accessors listed below. Poking at the internals is deprecated and subject to change in the future.

"get()" is a well-behaved overloaded version of the method in LWP::UserAgent. This lets you do things like

    $mech->get( $uri, ':content_file' => $tempfile );

and you can rest assured that the parms will get filtered down appropriately.

NOTE: Because ":content_file" causes the page contents to be stored in a file instead of the response object, some Mech functions that expect it to be there won't work as expected. Use with caution.

$mech->put( $uri, content => $content )

PUTs $content to $uri. Returns an HTTP::Response object. $uri can be a well-formed URI string, a URI object, or a WWW::Mechanize::Link object.

$mech->reload()

Acts like the reload button in a browser: repeats the current request. The history (as per the ``back'' method) is not altered.

Returns the HTTP::Response object from the reload, or "undef" if there's no current request.

$mech->back()

The equivalent of hitting the ``back'' button in a browser. Returns to the previous page. Won't go back past the first page. (Really, what would it do if it could?)

Returns true if it could go back, or false if not.

STATUS METHODS

$mech->success()

Returns a boolean telling whether the last request was successful. If there hasn't been an operation yet, returns false.

This is a convenience function that wraps "$mech->res->is_success".

$mech->uri()

Returns the current URI as a URI object. This object stringifies to the URI itself.

$mech->response() / $mech->res()

Return the current response as an HTTP::Response object.

Synonym for "$mech->response()"

$mech->status()

Returns the HTTP status code of the response. This is a 3-digit number like 200 for OK, 404 for not found, and so on.

$mech->ct() / $mech->content_type()

Returns the content type of the response.

$mech->base()

Returns the base URI for the current response

$mech->forms()

When called in a list context, returns a list of the forms found in the last fetched page. In a scalar context, returns a reference to an array with those forms. The forms returned are all HTML::Form objects.

$mech->current_form()

Returns the current form as an HTML::Form object.

$mech->links()

When called in a list context, returns a list of the links found in the last fetched page. In a scalar context it returns a reference to an array with those links. Each link is a WWW::Mechanize::Link object.

$mech->is_html()

Returns true/false on whether our content is HTML, according to the HTTP headers.

$mech->title()

Returns the contents of the "<TITLE>" tag, as parsed by HTML::HeadParser. Returns undef if the content is not HTML.

CONTENT-HANDLING METHODS

$mech->content(...)

Returns the content that the mech uses internally for the last page fetched. Ordinarily this is the same as "$mech->response()->decoded_content()", but this may differ for HTML documents if ``update_html'' is overloaded (in which case the value passed to the base-class implementation of same will be returned), and/or extra named arguments are passed to content():

$mech->content( format => 'text' ): Returns a text-only version of the page, with all HTML markup stripped. This feature requires HTML::TreeBuilder to be installed, or a fatal error will be thrown. This works only if the contents are HTML.
$mech->content( base_href => [$base_href|undef] ): Returns the HTML document, modified to contain a "<base href="$base_href">" mark-up in the header. $base_href is "$mech->base()" if not specified. This is handy to pass the HTML to e.g. HTML::Display. This works only if the contents are HTML.
$mech->content( raw => 1 ): Returns "$self->response()->content()", i.e. the raw contents from the response.
$mech->content( decoded_by_headers => 1 ): Returns the content after applying all "Content-Encoding" headers but with not additional mangling.
$mech->content( charset => $charset ): Returns "$self->response()->decoded_content(charset => $charset)" (see HTTP::Response for details).

To preserve backwards compatibility, additional parameters will be ignored unless none of "raw | decoded_by_headers | charset" is specified and the text is HTML, in which case an error will be triggered.

$mech->text()

Returns the text of the current HTML content. If the content isn't HTML, $mech will die.

The text is extracted by parsing the content, and then the extracted text is cached, so don't worry about performance of calling this repeatedly.

LINK METHODS

$mech->links()

Lists all the links on the current page. Each link is a WWW::Mechanize::Link object. In list context, returns a list of all links. In scalar context, returns an array reference of all links.

$mech->follow_link(...)

Follows a specified link on the page. You specify the match to be found using the same parms that "find_link()" uses.

Here some examples:

3rd link called ``download''

    $mech->follow_link( text => 'download', n => 3 );

first link where the URL has ``download'' in it, regardless of case:

    $mech->follow_link( url_regex => qr/download/i );

    $mech->follow_link( url_regex => qr/(?i:download)/ );

3rd link on the page
```
    $mech->follow_link( n => 3 );
```

the link with the url

    $mech->follow_link( url => '/other/page' );

    $mech->follow_link( url => 'http://example.com/page' );

Returns the result of the GET method (an HTTP::Response object) if a link was found. If the page has no links, or the specified link couldn't be found, returns undef.

$mech->find_link( ... )

Finds a link in the currently fetched page. It returns a WWW::Mechanize::Link object which describes the link. (You'll probably be most interested in the "url()" property.) If it fails to find a link it returns undef.

You can take the URL part and pass it to the "get()" method. If that's your plan, you might as well use the "follow_link()" method directly, since it does the "get()" for you automatically.

Note that "<FRAME SRC="...">" tags are parsed out of the the HTML and treated as links so this method works with them.

You can select which link to find by passing in one or more of these key/value pairs:

"text => 'string'," and "text_regex => qr/regex/,"
"text" matches the text of the link against string, which must be an exact match. To select a link with text that is exactly ``download'', use
```
    $mech->find_link( text => 'download' );
```
"text_regex" matches the text of the link against regex. To select a link with text that has ``download'' anywhere in it, regardless of case, use
```
    $mech->find_link( text_regex => qr/download/i );
```
Note that the text extracted from the page's links are trimmed. For example, "<a> foo </a>" is stored as 'foo', and searching for leading or trailing spaces will fail.
"url => 'string'," and "url_regex => qr/regex/,"
Matches the URL of the link against string or regex, as appropriate. The URL may be a relative URL, like foo/bar.html, depending on how it's coded on the page.
"url_abs => string" and "url_abs_regex => regex"
Matches the absolute URL of the link against string or regex, as appropriate. The URL will be an absolute URL, even if it's relative in the page.
"name => string" and "name_regex => regex"
Matches the name of the link against string or regex, as appropriate.
"id => string" and "id_regex => regex"
Matches the attribute 'id' of the link against string or regex, as appropriate.
"class => string" and "class_regex => regex"
Matches the attribute 'class' of the link against string or regex, as appropriate.
"tag => string" and "tag_regex => regex"
Matches the tag that the link came from against string or regex, as appropriate. The "tag_regex" is probably most useful to check for more than one tag, as in:
```
    $mech->find_link( tag_regex => qr/^(a|frame)$/ );
```
The tags and attributes looked at are defined below, at ``$mech->find_link() : link format''.

If "n" is not specified, it defaults to 1. Therefore, if you don't specify any parms, this method defaults to finding the first link on the page.

Note that you can specify multiple text or URL parameters, which will be ANDed together. For example, to find the first link with text of ``News'' and with ``cnn.com'' in the URL, use:

    $mech->find_link( text => 'News', url_regex => qr/cnn\.com/ );

The return value is a reference to an array containing a WWW::Mechanize::Link object for every link in "$self->content".

The links come from the following:

"<a href=...>"
"<area href=...>"
"<frame src=...>"
"<iframe src=...>"
"<link href=...>"
"<meta content=...>"

$mech->find_all_links( ... )

Returns all the links on the current page that match the criteria. The method for specifying link criteria is the same as in "find_link()". Each of the links returned is a WWW::Mechanize::Link object.

In list context, "find_all_links()" returns a list of the links. Otherwise, it returns a reference to the list of links.

"find_all_links()" with no parameters returns all links in the page.

$mech->find_all_inputs( ... criteria ... )

find_all_inputs() returns an array of all the input controls in the current form whose properties match all of the regexes passed in. The controls returned are all descended from HTML::Form::Input.

If no criteria are passed, all inputs will be returned.

If there is no current page, there is no form on the current page, or there are no submit controls in the current form then the return will be an empty array.

You may use a regex or a literal string:

    # get all textarea controls whose names begin with "customer"
    my @customer_text_inputs = $mech->find_all_inputs(
        type       => 'textarea',
        name_regex => qr/^customer/,
    );
    # get all text or textarea controls called "customer"
    my @customer_text_inputs = $mech->find_all_inputs(
        type_regex => qr/^(text|textarea)$/,
        name       => 'customer',
    );

$mech->find_all_submits( ... criteria ... )

"find_all_submits()" does the same thing as "find_all_inputs()" except that it only returns controls that are submit controls, ignoring other types of input controls like text and checkboxes.

IMAGE METHODS

$mech->images

Lists all the images on the current page. Each image is a WWW::Mechanize::Image object. In list context, returns a list of all images. In scalar context, returns an array reference of all images.

$mech->find_image()

Finds an image in the current page. It returns a WWW::Mechanize::Image object which describes the image. If it fails to find an image it returns undef.

You can select which image to find by passing in one or more of these key/value pairs:

"alt => 'string'" and "alt_regex => qr/regex/,"
"alt" matches the ALT attribute of the image against string, which must be an exact match. To select a image with an ALT tag that is exactly ``download'', use
```
    $mech->find_image( alt => 'download' );
```
"alt_regex" matches the ALT attribute of the image against a regular expression. To select an image with an ALT attribute that has ``download'' anywhere in it, regardless of case, use
```
    $mech->find_image( alt_regex => qr/download/i );
```
"url => 'string'," and "url_regex => qr/regex/,"
Matches the URL of the image against string or regex, as appropriate. The URL may be a relative URL, like foo/bar.html, depending on how it's coded on the page.
"url_abs => string" and "url_abs_regex => regex"
Matches the absolute URL of the image against string or regex, as appropriate. The URL will be an absolute URL, even if it's relative in the page.
"tag => string" and "tag_regex => regex"
Matches the tag that the image came from against string or regex, as appropriate. The "tag_regex" is probably most useful to check for more than one tag, as in:
```
    $mech->find_image( tag_regex => qr/^(img|input)$/ );
```
The tags supported are "<img>" and "<input>".

If "n" is not specified, it defaults to 1. Therefore, if you don't specify any parms, this method defaults to finding the first image on the page.

Note that you can specify multiple ALT or URL parameters, which will be ANDed together. For example, to find the first image with ALT text of ``News'' and with ``cnn.com'' in the URL, use:

    $mech->find_image( image => 'News', url_regex => qr/cnn\.com/ );

The return value is a reference to an array containing a WWW::Mechanize::Image object for every image in "$self->content".

$mech->find_all_images( ... )

Returns all the images on the current page that match the criteria. The method for specifying image criteria is the same as in "find_image()". Each of the images returned is a WWW::Mechanize::Image object.

In list context, "find_all_images()" returns a list of the images. Otherwise, it returns a reference to the list of images.

"find_all_images()" with no parameters returns all images in the page.

FORM METHODS

These methods let you work with the forms on a page. The idea is to choose a form that you'll later work with using the field methods below.

$mech->forms

Lists all the forms on the current page. Each form is an HTML::Form object. In list context, returns a list of all forms. In scalar context, returns an array reference of all forms.

$mech->form_number($number)

Selects the numberth form on the page as the target for subsequent calls to "field()" and "click()". Also returns the form that was selected.

If it is found, the form is returned as an HTML::Form object and set internally for later use with Mech's form methods such as "field()" and "click()".

Emits a warning and returns undef if no form is found.

The first form is number 1, not zero.

$mech->form_name( $name )

Selects a form by name. If there is more than one form on the page with that name, then the first one is used, and a warning is generated.

If it is found, the form is returned as an HTML::Form object and set internally for later use with Mech's form methods such as "field()" and "click()".

Returns undef if no form is found.

$mech->form_id( $name )

Selects a form by ID. If there is more than one form on the page with that ID, then the first one is used, and a warning is generated.

If it is found, the form is returned as an HTML::Form object and set internally for later use with Mech's form methods such as "field()" and "click()".

Returns undef if no form is found.

$mech->form_with_fields( @fields )

Selects a form by passing in a list of field names it must contain. If there is more than one form on the page with that matches, then the first one is used, and a warning is generated.

If it is found, the form is returned as an HTML::Form object and set internally for later used with Mech's form methods such as "field()" and "click()".

Returns undef if no form is found.

Note that this functionality requires libwww-perl 5.69 or higher.

FIELD METHODS

These methods allow you to set the values of fields in a given form.

$mech->field( $name, $value, $number )

$mech->field( $name, \@values, $number )

Given the name of a field, set its value to the value specified. This applies to the current form (as set by the ``form_name()'' or ``form_number()'' method or defaulting to the first form on the page).

The optional $number parameter is used to distinguish between two fields with the same name. The fields are numbered from 1.

$mech->select($name, $value)

$mech->select($name, \@values)

Given the name of a "select" field, set its value to the value specified. If the field is not "<select multiple>" and the $value is an array, only the first value will be set. [Note: the documentation previously claimed that only the last value would be set, but this was incorrect.] Passing $value as a hash with an "n" key selects an item by number (e.g. "{n => 3}" or "{n => [2,4]}"). The numbering starts at 1. This applies to the current form.

If you have a field with "<select multiple>" and you pass a single $value, then $value will be added to the list of fields selected, without clearing the others. However, if you pass an array reference, then all previously selected values will be cleared.

Returns true on successfully setting the value. On failure, returns false and calls "$self>warn()" with an error message.

$mech->set_fields( $name => $value ... )

This method sets multiple fields of the current form. It takes a list of field name and value pairs. If there is more than one field with the same name, the first one found is set. If you want to select which of the duplicate field to set, use a value which is an anonymous array which has the field value and its number as the 2 elements.

        # set the second foo field
        $mech->set_fields( $name => [ 'foo', 2 ] );

The fields are numbered from 1.

This applies to the current form.

$mech->set_visible( @criteria )

This method sets fields of the current form without having to know their names. So if you have a login screen that wants a username and password, you do not have to fetch the form and inspect the source (or use the mech-dump utility, installed with WWW::Mechanize) to see what the field names are; you can just say

    $mech->set_visible( $username, $password );

and the first and second fields will be set accordingly. The method is called set_visible because it acts only on visible fields; hidden form inputs are not considered. The order of the fields is the order in which they appear in the HTML source which is nearly always the order anyone viewing the page would think they are in, but some creative work with tables could change that; caveat user.

Each element in @criteria is either a field value or a field specifier. A field value is a scalar. A field specifier allows you to specify the type of input field you want to set and is denoted with an arrayref containing two elements. So you could specify the first radio button with

    $mech->set_visible( [ radio => 'KCRW' ] );

Field values and specifiers can be intermixed, hence

    $mech->set_visible( 'fred', 'secret', [ option => 'Checking' ] );

would set the first two fields to ``fred'' and ``secret'', and the next "OPTION" menu field to ``Checking''.

The possible field specifier types are: ``text'', ``password'', ``hidden'', ``textarea'', ``file'', ``image'', ``submit'', ``radio'', ``checkbox'' and ``option''.

"set_visible" returns the number of values set.

$mech->tick( $name, $value [, $set] )

``Ticks'' the first checkbox that has both the name and value associated with it on the current form. Dies if there is no named check box for that value. Passing in a false value as the third optional argument will cause the checkbox to be unticked.

$mech->untick($name, $value)

Causes the checkbox to be unticked. Shorthand for "tick($name,$value,undef)"

$mech->value( $name [, $number] )

Given the name of a field, return its value. This applies to the current form.

The optional $number parameter is used to distinguish between two fields with the same name. The fields are numbered from 1.

If the field is of type file (file upload field), the value is always cleared to prevent remote sites from downloading your local files. To upload a file, specify its file name explicitly.

$mech->click( $button [, $x, $y] )

Has the effect of clicking a button on the current form. The first argument is the name of the button to be clicked. The second and third arguments (optional) allow you to specify the (x,y) coordinates of the click.

If there is only one button on the form, "$mech->click()" with no arguments simply clicks that one button.

Returns an HTTP::Response object.

$mech->click_button( ... )

Has the effect of clicking a button on the current form by specifying its name, value, or index. Its arguments are a list of key/value pairs. Only one of name, number, input or value must be specified in the keys.

"name => name"
Clicks the button named name in the current form.
"number => n"
Clicks the nth button in the current form. Numbering starts at 1.
"value => value"
Clicks the button with the value value in the current form.
"input => $inputobject"
Clicks on the button referenced by $inputobject, an instance of HTML::Form::SubmitInput obtained e.g. from
```
    $mech->current_form()->find_input( undef, 'submit' )
```
$inputobject must belong to the current form.
"x => x"
"y => y"
These arguments (optional) allow you to specify the (x,y) coordinates of the click.

$mech->submit()

Submits the page, without specifying a button to click. Actually, no button is clicked at all.

Returns an HTTP::Response object.

This used to be a synonym for "$mech->click( 'submit' )", but is no longer so.

$mech->submit_form( ... )

This method lets you select a form from the previously fetched page, fill in its fields, and submit it. It combines the form_number/form_name, set_fields and click methods into one higher level call. Its arguments are a list of key/value pairs, all of which are optional.

"fields => \%fields"
Specifies the fields to be filled in the current form.
"with_fields => \%fields"
Probably all you need for the common case. It combines a smart form selector and data setting in one operation. It selects the first form that contains all fields mentioned in "\%fields". This is nice because you don't need to know the name or number of the form to do this.
(calls "form_with_fields()" and "set_fields()").
If you choose this, the form_number, form_name, form_id and fields options will be ignored.
"form_number => n"
Selects the nth form (calls "form_number()"). If this parm is not specified, the currently-selected form is used.
"form_name => name"
Selects the form named name (calls "form_name()")
"form_id => ID"
Selects the form with ID ID (calls "form_id()")
"button => button"
Clicks on button button (calls "click()")
"x => x, y => y"
Sets the x or y values for "click()"

If no form is selected, the first form found is used.

If button is not passed, then the "submit()" method is used instead.

If you want to submit a file and get its content from a scalar rather than a file in the filesystem, you can use:

    $mech->submit_form(with_fields => { logfile => [ [ undef, 'whatever', Content => $content ], 1 ] } );

Returns an HTTP::Response object.

MISCELLANEOUS METHODS

$mech->add_header( name => $value [, name => $value... ] )

Sets HTTP headers for the agent to add or remove from the HTTP request.

    $mech->add_header( Encoding => 'text/klingon' );

If a value is "undef", then that header will be removed from any future requests. For example, to never send a Referer header:

    $mech->add_header( Referer => undef );

If you want to delete a header, use "delete_header".

Returns the number of name/value pairs added.

NOTE: This method was very different in WWW::Mechanize before 1.00. Back then, the headers were stored in a package hash, not as a member of the object instance. Calling "add_header()" would modify the headers for every WWW::Mechanize object, even after your object no longer existed.

$mech->delete_header( name [, name ... ] )

Removes HTTP headers from the agent's list of special headers. For instance, you might need to do something like:

    # Don't send a Referer for this URL
    $mech->add_header( Referer => undef );
    # Get the URL
    $mech->get( $url );
    # Back to the default behavior
    $mech->delete_header( 'Referer' );

$mech->quiet(true/false)

Allows you to suppress warnings to the screen.

    $mech->quiet(0); # turns on warnings (the default)
    $mech->quiet(1); # turns off warnings
    $mech->quiet();  # returns the current quietness status

$mech->stack_depth( $max_depth )

Get or set the page stack depth. Use this if you're doing a lot of page scraping and running out of memory.

A value of 0 means ``no history at all.'' By default, the max stack depth is humongously large, effectively keeping all history.

$mech->save_content( $filename, %opts )

Dumps the contents of "$mech->content" into $filename. $filename will be overwritten. Dies if there are any errors.

If the content type does not begin with ``text/'', then the content is saved in binary mode (i.e. "binmode()" is set on the output filehandle).

Additional arguments can be passed as key/value pairs:

$mech->save_content( $filename, binary => 1 )

Filehandle is set with "binmode" to ":raw" and contents are taken calling "$self->content(decoded_by_headers => 1)". Same as calling:

    $mech->save_content( $filename, binmode => ':raw',
                         decoded_by_headers => 1 );

This should be the safest way to save contents verbatim.

$mech->save_content( $filename, binmode => $binmode )

Filehandle is set to binary mode. If $binmode begins with ':', it is passed as a parameter to "binmode":

    binmode $fh, $binmode;

otherwise the filehandle is set to binary mode if $binmode is true:

    binmode $fh;

all other arguments

are passed as-is to "$mech->content(%opts)". In particular, "decoded_by_headers" might come handy if you want to revert the effect of line compression performed by the web server but without further interpreting the contents (e.g. decoding it according to the charset).

$mech->dump_headers( [$fh] )

Prints a dump of the HTTP response headers for the most recent response. If $fh is not specified or is undef, it dumps to STDOUT.

Unlike the rest of the dump_* methods, $fh can be a scalar. It will be used as a file name.

$mech->dump_links( [[$fh], $absolute] )

Prints a dump of the links on the current page to $fh. If $fh is not specified or is undef, it dumps to STDOUT.

If $absolute is true, links displayed are absolute, not relative.

$mech->dump_images( [[$fh], $absolute] )

Prints a dump of the images on the current page to $fh. If $fh is not specified or is undef, it dumps to STDOUT.

If $absolute is true, links displayed are absolute, not relative.

$mech->dump_forms( [$fh] )

Prints a dump of the forms on the current page to $fh. If $fh is not specified or is undef, it dumps to STDOUT.

$mech->dump_text( [$fh] )

Prints a dump of the text on the current page to $fh. If $fh is not specified or is undef, it dumps to STDOUT.

OVERRIDDEN LWP::UserAgent METHODS

$mech->clone()

Clone the mech object. The clone will be using the same cookie jar as the original mech.

$mech->redirect_ok()

An overloaded version of "redirect_ok()" in LWP::UserAgent. This method is used to determine whether a redirection in the request should be followed.

Note that WWW::Mechanize's constructor pushes POST on to the agent's "requests_redirectable" list.

$mech->request( $request [, $arg [, $size]])

Overloaded version of "request()" in LWP::UserAgent. Performs the actual request. Normally, if you're using WWW::Mechanize, it's because you don't want to deal with this level of stuff anyway.

Note that $request will be modified.

Returns an HTTP::Response object.

$mech->update_html( $html )

Allows you to replace the HTML that the mech has found. Updates the forms and links parse-trees that the mech uses internally.

Say you have a page that you know has malformed output, and you want to update it so the links come out correctly:

    my $html = $mech->content;
    $html =~ s[</option>.{0,3}</td>][</option></select></td>]isg;
    $mech->update_html( $html );

This method is also used internally by the mech itself to update its own HTML content when loading a page. This means that if you would like to systematically perform the above HTML substitution, you would overload update_html in a subclass thusly:

   package MyMech;
   use base 'WWW::Mechanize';
   sub update_html {
       my ($self, $html) = @_;
       $html =~ s[</option>.{0,3}</td>][</option></select></td>]isg;
       $self->WWW::Mechanize::update_html( $html );
   }

If you do this, then the mech will use the tidied-up HTML instead of the original both when parsing for its own needs, and for returning to you through ``content''.

Overloading this method is also the recommended way of implementing extra validation steps (e.g. link checkers) for every HTML page received. ``warn'' and ``die'' would then come in handy to signal validation errors.

$mech->credentials( $username, $password )

Provide credentials to be used for HTTP Basic authentication for all sites and realms until further notice.

The four argument form described in LWP::UserAgent is still supported.

$mech->get_basic_credentials( $realm, $uri, $isproxy )

Returns the credentials for the realm and URI.

$mech->clear_credentials()

Remove any credentials set up with "credentials()".

INHERITED UNCHANGED LWP::UserAgent METHODS

As a subclass of LWP::UserAgent, WWW::Mechanize inherits all of LWP::UserAgent's methods. Many of which are overridden or extended. The following methods are inherited unchanged. View the LWP::UserAgent documentation for their implementation descriptions.

This is not meant to be an inclusive list. LWP::UA may have added others.