man Mojolicious::Controller (3): Controller base class

SYNOPSIS

# Controller
package MyApp::Controller::Foo;
use Mojo::Base 'Mojolicious::Controller';
# Action
sub bar {
my $self = shift;
my $name = $self->param('name');
$self->res->headers->cache_control('max-age=1, no-cache');
$self->render(json => {hello => $name});
}

DESCRIPTION

Mojolicious::Controller is the base class for your Mojolicious controllers. It is also the default controller class unless you set ``controller_class'' in Mojolicious.

ATTRIBUTES

Mojolicious::Controller inherits all attributes from Mojo::Base and implements the following new ones.

app

  my $app = $c->app;
  $c      = $c->app(Mojolicious->new);

A reference back to the application that dispatched to this controller, usually a Mojolicious object.

  # Use application logger
  $c->app->log->debug('Hello Mojo');
  # Generate path
  my $path = $c->app->home->rel_file('templates/foo/bar.html.ep');

match

  my $m = $c->match;
  $c    = $c->match(Mojolicious::Routes::Match->new);

Router results for the current request, defaults to a Mojolicious::Routes::Match object.

  # Introspect
  my $name   = $c->match->endpoint->name;
  my $foo    = $c->match->endpoint->pattern->defaults->{foo};
  my $action = $c->match->stack->[-1]{action};

tx

  my $tx = $c->tx;
  $c     = $c->tx(Mojo::Transaction::HTTP->new);

The transaction that is currently being processed, usually a Mojo::Transaction::HTTP or Mojo::Transaction::WebSocket object. Note that this reference is usually weakened, so the object needs to be referenced elsewhere as well when you're performing non-blocking operations and the underlying connection might get closed early.

  # Check peer information
  my $address = $c->tx->remote_address;
  my $port    = $c->tx->remote_port;
  # Increase size limit for WebSocket messages to 16MB
  $c->tx->max_websocket_size(16777216) if $c->tx->is_websocket;
  # Perform non-blocking operation without knowing the connection status
  my $tx = $c->tx;
  Mojo::IOLoop->timer(2 => sub {
    $c->app->log->debug($tx->is_finished ? 'Finished' : 'In progress');
  });

METHODS

Mojolicious::Controller inherits all methods from Mojo::Base and implements the following new ones.

continue

  $c->continue;

Continue dispatch chain from an intermediate destination with ``continue'' in Mojolicious::Routes.

cookie

  my $value = $c->cookie('foo');
  $c        = $c->cookie(foo => 'bar');
  $c        = $c->cookie(foo => 'bar', {path => '/'});

Access request cookie values and create new response cookies. If there are multiple values sharing the same name, and you want to access more than just the last one, you can use ``every_cookie''.

  # Create response cookie with domain and expiration date
  $c->cookie(user => 'sri', {domain => 'example.com', expires => time + 60});
  # Create secure response cookie
  $c->cookie(secret => 'I <3 Mojolicious', {secure => 1, httponly => 1});

every_cookie

  my $values = $c->every_cookie('foo');

Similar to ``cookie'', but returns all request cookie values sharing the same name as an array reference.

  $ Get first cookie value
  my $first = $c->every_cookie('foo')->[0];

every_param

  my $values = $c->every_param('foo');

Similar to ``param'', but returns all values sharing the same name as an array reference.

  # Get first value
  my $first = $c->every_param('foo')->[0];

every_signed_cookie

  my $values = $c->every_signed_cookie('foo');

Similar to ``signed_cookie'', but returns all signed request cookie values sharing the same name as an array reference.

  # Get first signed cookie value
  my $first = $c->every_signed_cookie('foo')->[0];

finish

  $c = $c->finish;
  $c = $c->finish(1000);
  $c = $c->finish(1003 => 'Cannot accept data!');
  $c = $c->finish('Bye!');

Close WebSocket connection or long poll stream gracefully. This method will automatically respond to WebSocket handshake requests with a 101 response status, to establish the WebSocket connection.

flash

  my $foo = $c->flash('foo');
  $c      = $c->flash({foo => 'bar'});
  $c      = $c->flash(foo => 'bar');

Data storage persistent only for the next request, stored in the ``session''.

  # Show message after redirect
  $c->flash(message => 'User created successfully!');
  $c->redirect_to('show_user', id => 23);

helpers

  my $helpers = $c->helpers;

Return a proxy object containing the current controller object and on which helpers provided by ``app'' can be called. This includes all helpers from Mojolicious::Plugin::DefaultHelpers and Mojolicious::Plugin::TagHelpers.

  # Make sure to use the "title" helper and not the controller method
  $c->helpers->title('Welcome!');
  # Use a nested helper instead of the "reply" controller method
  $c->helpers->reply->not_found;

on

  my $cb = $c->on(finish => sub {...});

Subscribe to events of ``tx'', which is usually a Mojo::Transaction::HTTP or Mojo::Transaction::WebSocket object. This method will automatically respond to WebSocket handshake requests with a 101 response status, to establish the WebSocket connection.

  # Do something after the transaction has been finished
  $c->on(finish => sub {
    my $c = shift;
    $c->app->log->debug('All data has been sent');
  });
  # Receive WebSocket message
  $c->on(message => sub {
    my ($c, $msg) = @_;
    $c->app->log->debug("Message: $msg");
  });
  # Receive JSON object via WebSocket message
  $c->on(json => sub {
    my ($c, $hash) = @_;
    $c->app->log->debug("Test: $hash->{test}");
  });
  # Receive WebSocket "Binary" message
  $c->on(binary => sub {
    my ($c, $bytes) = @_;
    my $len = length $bytes;
    $c->app->log->debug("Received $len bytes");
  });

param

  my $value = $c->param('foo');
  $c        = $c->param(foo => 'ba;r');
  $c        = $c->param(foo => 'ba;r', 'baz');
  $c        = $c->param(foo => ['ba;r', 'baz']);

Access route placeholder values that are not reserved stash values, file uploads as well as "GET" and "POST" parameters extracted from the query string and "application/x-www-form-urlencoded" or "multipart/form-data" message body, in that order. If there are multiple values sharing the same name, and you want to access more than just the last one, you can use ``every_param''. Parts of the request body need to be loaded into memory to parse "POST" parameters, so you have to make sure it is not excessively large, there's a 16MB limit by default.

  # Get first value
  my $first = $c->every_param('foo')->[0];

For more control you can also access request information directly.

  # Only GET parameters
  my $foo = $c->req->query_params->param('foo');
  # Only POST parameters
  my $foo = $c->req->body_params->param('foo');
  # Only GET and POST parameters
  my $foo = $c->req->param('foo');
  # Only file uploads
  my $foo = $c->req->upload('foo');

redirect_to

  $c = $c->redirect_to('named', foo => 'bar');
  $c = $c->redirect_to('named', {foo => 'bar'});
  $c = $c->redirect_to('/index.html');
  $c = $c->redirect_to('http://example.com/index.html');

Prepare a 302 (if the status code is not already "3xx") redirect response with "Location" header, takes the same arguments as ``url_for''.

  # Moved Permanently
  $c->res->code(301);
  $c->redirect_to('some_route');
  # Temporary Redirect
  $c->res->code(307);
  $c->redirect_to('some_route');

render

  my $bool = $c->render;
  my $bool = $c->render(foo => 'bar', baz => 23);
  my $bool = $c->render(template => 'foo/index');
  my $bool = $c->render(template => 'index', format => 'html');
  my $bool = $c->render(data => $bytes);
  my $bool = $c->render(text => 'Hello!');
  my $bool = $c->render(json => {foo => 'bar'});
  my $bool = $c->render(handler => 'something');
  my $bool = $c->render('foo/index');

Render content with ``renderer'' in Mojolicious and emit hooks ``before_render'' in Mojolicious as well as ``after_render'' in Mojolicious, or call ``reply->not_found'' in Mojolicious::Plugin::DefaultHelpers if no response could be generated, all additional key/value pairs get merged into the ``stash''.

  # Render characters
  $c->render(text => 'I ♥ Mojolicious!');
  # Render characters (alternative)
  $c->stash(text => 'I ♥ Mojolicious!')->render;
  # Render binary data
  use Mojo::JSON 'encode_json';
  $c->render(data => encode_json({test => 'I ♥ Mojolicious!'}));
  # Render JSON
  $c->render(json => {test => 'I ♥ Mojolicious!'});
  # Render inline template
  $c->render(inline => '<%= 1 + 1 %>');
  # Render template "foo/bar.html.ep"
  $c->render(template => 'foo/bar', format => 'html', handler => 'ep');
  # Render template "test.*.*" with arbitrary values "foo" and "bar"
  $c->render(template => 'test', foo => 'test', bar => 23);
  # Render template "test.xml.*"
  $c->render(template => 'test', format => 'xml');
  # Render template "test.xml.*" (alternative)
  $c->render('test', format => 'xml');

render_later

  $c = $c->render_later;

Disable automatic rendering to delay response generation, only necessary if automatic rendering would result in a response.

  # Delayed rendering
  $c->render_later;
  Mojo::IOLoop->timer(2 => sub {
    $c->render(text => 'Delayed by 2 seconds!');
  });

render_maybe

  my $bool = $c->render_maybe;
  my $bool = $c->render_maybe(foo => 'bar', baz => 23);
  my $bool = $c->render_maybe('foo/index', format => 'html');

Try to render content, but do not call ``reply->not_found'' in Mojolicious::Plugin::DefaultHelpers if no response could be generated, takes the same arguments as ``render''.

  # Render template "index_local" only if it exists
  $c->render_maybe('index_local') or $c->render('index');

render_to_string

  my $output = $c->render_to_string('foo/index', format => 'pdf');

Try to render content and return it wrapped in a Mojo::ByteStream object or return "undef", all arguments get localized automatically and are only available during this render operation, takes the same arguments as ``render''.

  # Render inline template
  my $two = $c->render_to_string(inline => '<%= 1 + 1 %>');

rendered

  $c = $c->rendered;
  $c = $c->rendered(302);

Finalize response and emit hook ``after_dispatch'' in Mojolicious, defaults to using a 200 response code.

  # Custom response
  $c->res->headers->content_type('text/plain');
  $c->res->body('Hello World!');
  $c->rendered(200);

req

  my $req = $c->req;

Get Mojo::Message::Request object from ``tx''.

  # Longer version
  my $req = $c->tx->req;
  # Extract request information
  my $url    = $c->req->url->to_abs;
  my $info   = $c->req->url->to_abs->userinfo;
  my $host   = $c->req->url->to_abs->host;
  my $agent  = $c->req->headers->user_agent;
  my $custom = $c->req->headers->header('Custom-Header');
  my $bytes  = $c->req->body;
  my $str    = $c->req->text;
  my $hash   = $c->req->params->to_hash;
  my $value  = $c->req->json;
  my $foo    = $c->req->json('/23/foo');
  my $dom    = $c->req->dom;
  my $bar    = $c->req->dom('div.bar')->first->text;

res

  my $res = $c->res;

Get Mojo::Message::Response object from ``tx''.

  # Longer version
  my $res = $c->tx->res;
  # Force file download by setting a response header
  $c->res->headers->content_disposition('attachment; filename=foo.png;');
  # Use a custom response header
  $c->res->headers->header('Custom-Header' => 'whatever');
  # Make sure response is cached correctly
  $c->res->headers->cache_control('public, max-age=300');
  $c->res->headers->append(Vary => 'Accept-Encoding');

respond_to

  $c = $c->respond_to(
    json => {json => {message => 'Welcome!'}},
    html => {template => 'welcome'},
    any  => sub {...}
  );

Automatically select best possible representation for resource from "Accept" request header, "format" stash value or "format" "GET"/"POST" parameter, defaults to ``default_format'' in Mojolicious::Renderer or rendering an empty 204 response. Each representation can be handled with a callback or a hash reference containing arguments to be passed to ``render''. Since browsers often don't really know what they actually want, unspecific "Accept" request headers with more than one MIME type will be ignored, unless the "X-Requested-With" header is set to the value "XMLHttpRequest".

  # Everything else than "json" and "xml" gets a 204 response
  $c->respond_to(
    json => sub { $c->render(json => {just => 'works'}) },
    xml  => {text => '<just>works</just>'},
    any  => {data => '', status => 204}
  );

For more advanced negotiation logic you can also use the helper ``accepts'' in Mojolicious::Plugin::DefaultHelpers.

send

  $c = $c->send({binary => $bytes});
  $c = $c->send({text   => $bytes});
  $c = $c->send({json   => {test => [1, 2, 3]}});
  $c = $c->send([$fin, $rsv1, $rsv2, $rsv3, $op, $payload]);
  $c = $c->send($chars);
  $c = $c->send($chars => sub {...});

Send message or frame non-blocking via WebSocket, the optional drain callback will be executed once all data has been written. This method will automatically respond to WebSocket handshake requests with a 101 response status, to establish the WebSocket connection.

  # Send "Text" message
  $c->send('I ♥ Mojolicious!');
  # Send JSON object as "Text" message
  $c->send({json => {test => 'I ♥ Mojolicious!'}});
  # Send JSON object as "Binary" message
  use Mojo::JSON 'encode_json';
  $c->send({binary => encode_json({test => 'I ♥ Mojolicious!'})});
  # Send "Ping" frame
  use Mojo::WebSocket 'WS_PING';
  $c->send([1, 0, 0, 0, WS_PING, 'Hello World!']);
  # Make sure the first message has been written before continuing
  $c->send('First message!' => sub {
    my $c = shift;
    $c->send('Second message!');
  });

For mostly idle WebSockets you might also want to increase the inactivity timeout with ``inactivity_timeout'' in Mojolicious::Plugin::DefaultHelpers, which usually defaults to 15 seconds.

  # Increase inactivity timeout for connection to 300 seconds
  $c->inactivity_timeout(300);

session

  my $session = $c->session;
  my $foo     = $c->session('foo');
  $c          = $c->session({foo => 'bar'});
  $c          = $c->session(foo => 'bar');

Persistent data storage for the next few requests, all session data gets serialized with Mojo::JSON and stored Base64 encoded in HMAC-SHA1 signed cookies, to prevent tampering. Note that cookies usually have a 4096 byte (4KB) limit, depending on browser.

  # Manipulate session
  $c->session->{foo} = 'bar';
  my $foo = $c->session->{foo};
  delete $c->session->{foo};
  # Expiration date in seconds from now (persists between requests)
  $c->session(expiration => 604800);
  # Expiration date as absolute epoch time (only valid for one request)
  $c->session(expires => time + 604800);
  # Delete whole session by setting an expiration date in the past
  $c->session(expires => 1);

signed_cookie

  my $value = $c->signed_cookie('foo');
  $c        = $c->signed_cookie(foo => 'bar');
  $c        = $c->signed_cookie(foo => 'bar', {path => '/'});

Access signed request cookie values and create new signed response cookies. If there are multiple values sharing the same name, and you want to access more than just the last one, you can use ``every_signed_cookie''. Cookies are cryptographically signed with HMAC-SHA1, to prevent tampering, and the ones failing signature verification will be automatically discarded.

stash

  my $hash = $c->stash;
  my $foo  = $c->stash('foo');
  $c       = $c->stash({foo => 'bar', baz => 23});
  $c       = $c->stash(foo => 'bar', baz => 23);

Non-persistent data storage and exchange for the current request, application wide default values can be set with ``defaults'' in Mojolicious. Some stash values have a special meaning and are reserved, the full list is currently "action", "app", "cb", "controller", "data", "extends", "format", "handler", "inline", "json", "layout", "namespace", "path", "status", "template", "text" and "variant". Note that all stash values with a "mojo.*" prefix are reserved for internal use.

  # Remove value
  my $foo = delete $c->stash->{foo};
  # Assign multiple values at once
  $c->stash(foo => 'test', bar => 23);

url_for

  my $url = $c->url_for;
  my $url = $c->url_for(name => 'sebastian');
  my $url = $c->url_for({name => 'sebastian'});
  my $url = $c->url_for('test', name => 'sebastian');
  my $url = $c->url_for('test', {name => 'sebastian'});
  my $url = $c->url_for('/index.html');
  my $url = $c->url_for('//example.com/index.html');
  my $url = $c->url_for('http://example.com/index.html');
  my $url = $c->url_for('mailto:[email protected]');
  my $url = $c->url_for('#whatever');

Generate a portable Mojo::URL object with base for a path, URL or route.

  # "http://127.0.0.1:3000/index.html" if application was started with Morbo
  $c->url_for('/index.html')->to_abs;
  # "https://127.0.0.1:443/index.html" if application was started with Morbo
  $c->url_for('/index.html')->to_abs->scheme('https')->port(443);
  # "/index.html?foo=bar" if application is deployed under "/"
  $c->url_for('/index.html')->query(foo => 'bar');
  # "/myapp/index.html?foo=bar" if application is deployed under "/myapp"
  $c->url_for('/index.html')->query(foo => 'bar');

You can also use the helper ``url_with'' in Mojolicious::Plugin::DefaultHelpers to inherit query parameters from the current request.

  # "/list?q=mojo&page=2" if current request was for "/list?q=mojo&page=1"
  $c->url_with->query([page => 2]);

validation

  my $validation = $c->validation;

Get Mojolicious::Validator::Validation object for current request to validate file uploads as well as "GET" and "POST" parameters extracted from the query string and "application/x-www-form-urlencoded" or "multipart/form-data" message body. Parts of the request body need to be loaded into memory to parse "POST" parameters, so you have to make sure it is not excessively large, there's a 16MB limit by default.

  # Validate GET/POST parameter
  my $validation = $c->validation;
  $validation->required('title', 'trim')->size(3, 50);
  my $title = $validation->param('title');
  # Validate file upload
  my $validation = $c->validation;
  $validation->required('tarball')->upload->size(1, 1048576);
  my $tarball = $validation->param('tarball');

write

  $c = $c->write;
  $c = $c->write('');
  $c = $c->write($bytes);
  $c = $c->write($bytes => sub {...});

Write dynamic content non-blocking, the optional drain callback will be executed once all data has been written. Calling this method without a chunk of data will finalize the response headers and allow for dynamic content to be written later.

  # Keep connection alive (with Content-Length header)
  $c->res->headers->content_length(6);
  $c->write('Hel' => sub {
    my $c = shift;
    $c->write('lo!');
  });
  # Close connection when finished (without Content-Length header)
  $c->write('Hel' => sub {
    my $c = shift;
    $c->write('lo!' => sub {
      my $c = shift;
      $c->finish;
    });
  });

You can call ``finish'' or write an empty chunk of data at any time to end the stream.

  HTTP/1.1 200 OK
  Date: Sat, 13 Sep 2014 16:48:29 GMT
  Content-Length: 6
  Server: Mojolicious (Perl)
  Hello!
  HTTP/1.1 200 OK
  Connection: close
  Date: Sat, 13 Sep 2014 16:48:29 GMT
  Server: Mojolicious (Perl)
  Hello!

For Comet (long polling) you might also want to increase the inactivity timeout with ``inactivity_timeout'' in Mojolicious::Plugin::DefaultHelpers, which usually defaults to 15 seconds.

  # Increase inactivity timeout for connection to 300 seconds
  $c->inactivity_timeout(300);

write_chunk

  $c = $c->write_chunk;
  $c = $c->write_chunk('');
  $c = $c->write_chunk($bytes);
  $c = $c->write_chunk($bytes => sub {...});

Write dynamic content non-blocking with chunked transfer encoding, the optional drain callback will be executed once all data has been written. Calling this method without a chunk of data will finalize the response headers and allow for dynamic content to be written later.

  # Make sure previous chunk has been written before continuing
  $c->write_chunk('H' => sub {
    my $c = shift;
    $c->write_chunk('ell' => sub {
      my $c = shift;
      $c->finish('o!');
    });
  });