VERSION

version 4.022

DESCRIPTION

Create a command line tool with your Mo, Moo, Moose objects.

Everything is explicit. You have an "option" keyword to replace the usual "has" to explicitly use your attribute into the command line.

The "option" keyword takes additional parameters and uses Getopt::Long::Descriptive to generate a command line tool.

SYNOPSIS

In myOptions.pm :

package myOptions;
use Moo;
use MooX::Options;
option 'show_this_file' => (
is => 'ro',
format => 's',
required => 1,
doc => 'the file to display'
);
1;

In myTool.pl :

  use feature 'say';
  use myOptions;
  use Path::Class;
  my $opt = myOptions->new_with_options;
  say "Content of the file : ",
       file($opt->show_this_file)->slurp;

To use it :

  perl myTool.pl --show_this_file=myFile.txt
  Content of the file: myFile content

The help message :

  perl myTool.pl --help
  USAGE: myTool.pl [-h] [long options...]
      --show_this_file: String
          the file to display
      -h --help:
          show this help message
      --man:
          show the manual

The usage message :

  perl myTool.pl --usage
  USAGE: myTool.pl [ --show_this_file=String ] [ --usage ] [ --help ] [ --man ]

The manual :

  perl myTool.pl --man

METHODS

croak

Call Carp::croak dynamically

IMPORTED METHODS

The list of the methods automatically imported into your class.

new_with_options

It will parse your command line params and your inline params, validate and call the "new" method.

  myTool --str=ko
  t->new_with_options()->str # ko
  t->new_with_options(str => 'ok')->str #ok

option

The "option" keyword replaces the "has" method and adds support for special options for the command line only.

See ``OPTION PARAMETERS'' for the documentation.

options_usage | --help

It displays the usage message and returns the exit code.

  my $t = t->new_with_options();
  my $exit_code = 1;
  my $pre_message = "str is not valid";
  $t->options_usage($exit_code, $pre_message);

This method is also automatically fired if the command option ``--help'' is passed.

  myTool --help

options_man | --man

It displays the manual.

  my $t = t->new_with_options();
  $t->options_man();

This is automatically fired if the command option ``--man'' is passed.

  myTool --man

options_short_usage | --usage

It displays a short version of the help message.

  my $t = t->new_with_options();
  $t->options_short_usage($exit_code);

This is automatically fired if the command option ``--usage'' is passed.

  myTool --usage

IMPORT PARAMETERS

The list of parameters supported by MooX::Options.

flavour

Passes extra arguments for Getopt::Long::Descriptive. It is useful if you want to configure Getopt::Long.

  use MooX::Options flavour => [qw( pass_through )];

Any flavour is passed to Getopt::Long as a configuration, check the doc to see what is possible.

protect_argv

By default, @ARGV is protected. If you want to do something else on it, use this option and it will change the real @ARGV.

  use MooX::Options protect_argv => 0;

skip_options

If you have Role with options and you want to deactivate some of them, you can use this parameter. In that case, the "option" keyword will just work like an "has".

  use MooX::Options skip_options => [qw/multi/];

prefer_commandline

By default, arguments passed to "new_with_options" have a higher priority than the command line options.

This parameter will give the command line an higher priority.

  use MooX::Options prefer_commandline => 1;

with_config_from_file

This parameter will load MooX::ConfigFromFile in your module. The config option will be used between the command line and parameters.

myTool :

  use MooX::Options with_config_from_file => 1;

In /etc/myTool.json

  {"test" : 1}

usage_string

This parameter is passed to Getopt::Long::Descriptive::describe_options() as the first parameter.

It is a ``sprintf''-like string that is used in generating the first line of the usage message. It's a one-line summary of how the command is to be invoked. The default value is ``USAGE: %c %o''.

%c will be replaced with what Getopt::Long::Descriptive thinks is the program name (it's computed from $0, see ``prog_name'').

%o will be replaced with a list of the short options, as well as the text ``[long options...]'' if any have been defined.

The rest of the usage description can be used to summarize what arguments are expected to follow the program's options, and is entirely free-form.

Literal ``%'' characters will need to be written as ``%%'', just like with ``sprintf''.

spacer

This indicate the char to use for spacer. Please only use 1 char otherwize the text will be too long.

The default char is `` ''.

  use MooX::Options space => '+'

Then the ``spacer_before'' and ``spacer_after'' will use it for ``man'' and ``help'' message.

  option 'x' => (is => 'ro', spacer_before => 1, spacer_after => 1);

OPTION PARAMETERS

The keyword "option" extend the keyword "has" with specific parameters for the command line.

doc | documentation

Documentation for the command line option.

long_doc

Documentation for the man page. By default the "doc" parameter will be used.

See also Man parameters to get more examples how to build a nice man page.

required

This attribute indicates that the parameter is mandatory. This attribute is not really used by MooX::Options but ensures that consistent error message will be displayed.

format

Format of the params, same as Getopt::Long::Descriptive.

• i : integer
• i@: array of integer
• s : string
• s@: array of string
• f : float value

By default, it's a boolean value.

Take a look of available formats with Getopt::Long::Descriptive.

You need to understand that everything is explicit here. If you use Moose and your attribute has "isa => 'Array[Int]'", that will not imply the format "i@".

format json : special format support

The parameter will be treated like a json string.

  option 'hash' => (is => 'ro', json => 1);

You can also use the json format

  option 'hash' => (is => 'ro', format => "json");
  myTool --hash='{"a":1,"b":2}' # hash = { a => 1, b => 2 }

negativable

It adds the negative version for the option.

  option 'verbose' => (is => 'ro', negativable => 1);
  myTool --verbose    # verbose = 1
  myTool --no-verbose # verbose = 0

repeatable

It appends to the ``format'' the array attribute "@".

I advise to add a default value to your attribute to always have an array. Otherwise the default value will be an undefined value.

  option foo => (is => 'rw', format => 's@', default => sub { [] });
  myTool --foo="abc" --foo="def" # foo = ["abc", "def"]

autosplit

For repeatable option, you can add the autosplit feature with your specific parameters.

  option test => (is => 'ro', format => 'i@', default => sub {[]}, autosplit => ',');
  
  myTool --test=1 --test=2 # test = (1, 2)
  myTool --test=1,2,3      # test = (1, 2, 3)

It will also handle quoted params with the autosplit.

  option testStr => (is => 'ro', format => 's@', default => sub {[]}, autosplit => ',');
  myTool --testStr='a,b,"c,d",e,f' # testStr ("a", "b", "c,d", "e", "f")

autorange

For another repeatable option you can add the autorange feature with your specific parameters. This allows you to pass number ranges instead of passing each individual number.

  option test => (is => 'ro', format => 'i@', default => sub {[]}, autorange => 1);
  
  myTool --test=1 --test=2 # test = (1, 2)
  myTool --test=1,2,3      # test = (1, 2, 3)
  myTool --test=1,2,3..6   # test = (1, 2, 3, 4, 5, 6)

It will also handle quoted params like "autosplit", and will not rangify them.

  option testStr => (is => 'ro', format => 's@', default => sub {[]}, autorange => 1);
  myTool --testStr='1,2,"3,a,4",5' # testStr (1, 2, "3,a,4", 5)

"autosplit" will be set to ',' if undefined. You may set "autosplit" to a different delimiter than ',' for your group separation, but the range operator '..' cannot be changed.

  option testStr => (is => 'ro', format => 's@', default => sub {[]}, autorange => 1, autosplit => '-');
  myTool --testStr='1-2-3-5..7' # testStr (1, 2, 3, 5, 6, 7)

short

Long option can also have short version or aliased.

  option 'verbose' => (is => 'ro', short => 'v');
  myTool --verbose # verbose = 1
  myTool -v        # verbose = 1
  option 'account_id' => (is => 'ro', format => 'i', short => 'a|id');
  myTool --account_id=1
  myTool -a=1
  myTool --id=1

You can also use a shorter option without attribute :

  option 'account_id' => (is => 'ro', format => 'i');
  myTool --acc=1
  myTool --account=1

order

Specifies the order of the attribute. If you want to push some attributes at the end of the list. By default all options have an order set to 0, and options are sorted by their names.

  option 'at_the_end' => (is => 'ro', order => 999);

hidden

Hide option from doc but still an option you can use on command line.

  option 'debug' => (is => 'ro', doc => 'hidden');

Or

  option 'debug' => (is => 'ro', hidden => 1);

spacer_before, spacer_after

Add spacer before or after or both the params

  option 'myoption' => (is => 'ro', spacer_before => 1, spacer_after => 1);

ADDITIONAL MANUALS

• Man parameters
• Using namespace::clean
• Manage your tools with MooX::Cmd

EXTERNAL EXAMPLES

• Slide3D about MooX::Options <http://perltalks.celogeek.com/slides/2012/08/moox-options-slide3d.html>

Translation

Translation is now supported.

Use the dzil command to update the pot and merge into the po files.

• dzil msg-init

  Create a new language po

• dzil msg-scan

  Scan and generate or update the pot file

• dzil msg-merge

  Update all languages using the pot file

THANKS

• sschober

  For implementation and German translation.

THANKS

• Matt S. Trout (mst) <[email protected]>

  For his patience and advice.

• Tomas Doran (t0m) <[email protected]>

  To help me release the new version, and using it :)

• Torsten Raudssus (Getty)

  to use it a lot in DuckDuckGo <http://duckduckgo.com> (go to see MooX module also)

• Jens Rehsack (REHSACK)

  Use with PkgSrc <http://www.pkgsrc.org/>, and many really good idea (MooX::Cmd, MooX::ConfigFromFile, and more to come I'm sure)

• All contributors

  For improving and add more feature to MooX::Options

AUTHOR

celogeek <[email protected]>

COPYRIGHT AND LICENSE

This software is copyright (c) 2013 by celogeek <[email protected]>.

This is free software; you can redistribute it and/or modify it under the same terms as the Perl 5 programming language system itself.